<%

'+------------------
'| Amazon Light - ASIN Detail page
'+------------------

If (Request("asin") <> "") Then
	szAsin = Request("asin")
Else
	szAsin = "0967786002"
End if

'+------------------
'| Grab variables from querystring if they exist
'|  - szSchType = Type of main category -
'|		(books,elec,game,home)
'|  - szSchMode = Type of sub category (none = books) -
'|		(music,dvd,pc-hardware,software,toys,videogames,kitchen,universal,
'| 		garden,magazines,vhs,electronics,baby,photo)
'| 	- Request("term") and Request("field-keywords") are equivalent - just
'|		supporting old code by including "term"
'+------------------

If (Request("schMod") <> "") Then
	szSchMode = Request("schMod")
Else
	szSchMode = "books"
End if

szSchType = Request("type")

If (Request("sb") = "o") Then
	szSB = "o"
Else
	szSB = "s"
End if

If ((Request("term") <> "") OR (Request("field-keywords") <> "")) Then
	szTerm = Replace(Request("term")," ","+")
	If szTerm = "" Then
		szTerm = Replace(Request("field-keywords")," ","+")
	End if
Else
	If szSB = "s" Then
		szTerm = "Whittier Alaska"
	Else
		szTerm = ""
	End if
End if

'+------------------
'| Build the XML URL, and fetch the XML doc from Amazon
'+------------------

dim objHTTP
dim objXML
dim szGetString
dim rgReviews()

set objHTTP = Server.CreateObject("Microsoft.XMLHTTP")

szGetString = "http://xml.amazon.com/onca/xml?v=1.0&t=kokogiak-20&dev-t=[Insert Developer's Token Here]&AsinSearch=" & szAsin & "&type=heavy&f=xml"

objHTTP.open "GET", szGetString, false
objHTTP.Send
Set objXML = objHTTP.ResponseXML

If (objXML.getElementsByTagName("error").length=0) Then
	totProds = objXML.getElementsByTagName("Details").length

	For i = 0 to (totProds-1)

		set o15 = objXML.getElementsByTagName("Details").item(i)

		set o16 = o15.childNodes
		For j = 0 to o16.length-1
			Select Case o16.item(j).nodeName
			Case "Asin" szAsin = o16.item(j).text
			Case "ProductName" szProductName = o16.item(j).text
			Case "Isbn" szIsbn = o16.item(j).text
			Case "Upc" szUpc = o16.item(j).text
			Case "Manufacturer" szManufacturer = o16.item(j).text
			Case "Distributor" szDistributor = o16.item(j).text
			Case "Binding" szBinding = o16.item(j).text
			Case "ReadingLevel" szReadingLevel = o16.item(j).text
			Case "Publisher" szPublisher = o16.item(j).text
			Case "Media" szMedia = o16.item(j).text
			Case "Rank" szRank = o16.item(j).text
			Case "OurPrice" szOurPrice = o16.item(j).text
			Case "ListPrice" szListPrice = o16.item(j).text
			Case "UsedPrice" szUsedPrice = o16.item(j).text
			Case "RefurbishedPrice" szRefurbishedPrice = o16.item(j).text
			Case "AvgCustomerRating" szAvgCustomerRating = o16.item(j).text
			Case "AgeGroup" szAgeGroup = o16.item(j).text
			Case "EsrbRating" szEsrbRating = o16.item(j).text
			Case "MpaaRating" szMpaaRating = o16.item(j).text
			Case "Encoding" szEncoding = o16.item(j).text
			Case "ReleaseDate" szReleaseDate = o16.item(j).text
			Case "Availability" szAvailability = o16.item(j).text
			Case "ImageUrlLarge" szImageUrlLarge = o16.item(j).text
			Case "ImageUrlMedium" szImageUrlMedium = o16.item(j).text
			Case "ImageUrlSmall" szImageUrlSmall = o16.item(j).text
			Case "TheatricalRelease" szTheatricalRelease = o16.item(j).text
			Case "SalesRank" szSalesRank = o16.item(j).text
			Case "SimilarProducts" szSimilarProducts = o16.item(j).text
			Case "Authors"
				totAuths = objXML.getElementsByTagName("Author").length
				For k = 0 to (totAuths-1)
					If (k<totAuths-1) Then szCom = ", " Else szCom = "" End if
					set o17 = objXML.getElementsByTagName("Authors").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Author" szAuthors = szAuthors & o18.item(k).text & szCom
					End Select
				Next
			Case "Artists"
				totArts = objXML.getElementsByTagName("Artist").length
				For k = 0 to (totArts-1)
					If (k<totArts-1) Then szCom = ", " Else szCom = "" End if
					set o17 = objXML.getElementsByTagName("Artists").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Artist" szArtists = szArtists & o18.item(k).text & szCom
					End Select
				Next
			Case "Reviews"
				totReviews = objXML.getElementsByTagName("CustomerReview").length
				szAvgCustomerRating = objXML.getElementsByTagName("AvgCustomerRating").item(0).text
				ReDim rgReviews(totReviews)
				For k = 0 to (totReviews-1)
					set o17 = objXML.getElementsByTagName("CustomerReview").item(k)
					set o20 = o17.childNodes
					For l = 0 to 2
						Select Case o20.item(l).nodeName
							Case "Rating" rgReviews(k) = rgReviews(k) & "<b>Rating: </b>" & o20.item(l).text & " (out of 5)<br>"
							Case "Summary" rgReviews(k) = rgReviews(k) & "<b>Summary: </b>" & o20.item(l).text & "<br>"
							Case "Comment" rgReviews(k) = rgReviews(k) & "<b>Comment: </b>" & o20.item(l).text & "<br>"
						End Select
					Next
				Next
			Case "Platforms" szPlatforms = o16.item(j).text
			Case "Platform" szPlatform = o16.item(j).text
			Case "Starring"
				totActors = objXML.getElementsByTagName("Actor").length
				For k = 0 to (totActors-1)
					set o17 = objXML.getElementsByTagName("Starring").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Actor"
								szActor = Replace((Replace(o18.item(k).text," ","%20")),"'","%27")
''Add the IMDB/Google/TV/Shatner Number icons
								szActors = szActors & " • <a href='results.asp?advSearch=3&schMod=dvd&field-keywords=" & Server.URLEncode(Replace(o18.item(k).text,","," ")) & "'>" & o18.item(k).text & "</a> <a target='_new' href='http://us.imdb.com/Name?" & szActor & "'><img hspace=1 border=0 height=13 width=13 src='si.gif' alt='IMDB Listing' align=absmiddle></a><a target='_new' href='http://www.google.com/search?q=" & szActor & "'><img hspace=1 border=0 height=13 width=13 src='sg.gif' alt='Google Search' align=absmiddle></a><a target='_new' href='http://search.tv.yahoo.com/tvtitlesearch?p=+{" & Chr(34) & szActor & Chr(34) & "}+lineup:Pacific&s=utn&lineup=us_Pacific&range=14&title=" & szActor & "&lineup_tz=America/Los_Angeles&sort=time'><img hspace=1 border=0 height=13 width=13 src='st.gif' alt='Upcoming TV Appearances (US, Pacific Time, Next 14 Days)' align=absmiddle></a><a target='_new' href='http://oracleofbacon.org/cgi-bin/oracle/movielinks?firstname=William+Shatner&secondname=" & szActor & "'><img hspace=1 border=0 height=13 width=13 src='ss.gif' alt='Shatner Number' align=absmiddle></a><br>"
					End Select
				Next
			Case "Directors"
				totDirectors = objXML.getElementsByTagName("Director").length
				For k = 0 to (totDirectors-1)
					If (k<totDirectors-1) Then szCom = ", " Else szCom = "" End if
					set o17 = objXML.getElementsByTagName("Directors").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Director"
							szDirector = Replace((Replace(o18.item(k).text," ","%20")),"'","%27")
''Add the IMDB/Google icons
							szDirectors = szDirectors & " • <a href='results.asp?advSearch=4&schMod=dvd&field-keywords=" & Server.URLEncode(Replace(o18.item(k).text,","," ")) & "'>" & o18.item(k).text & "</a> <a target='_new' href='http://us.imdb.com/Name?" & szDirector & "'><img hspace=1 border=0 height=13 width=13 src='si.gif' alt='IMDB Listing' align=absmiddle></a><a target='_new' href='http://www.google.com/search?q=" & szDirector & "'><img hspace=1 border=0 height=13 width=13 src='sg.gif' alt='Google Search' align=absmiddle></a><br>"
					End Select
				Next
			Case "Features"
				totFeatures = objXML.getElementsByTagName("Feature").length
				For k = 0 to (totFeatures-1)
					set o17 = objXML.getElementsByTagName("Features").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Feature" szFeatures = szFeatures & " • " & o18.item(k).text & "<br>"
					End Select
				Next
			Case "Tracks"
				totTracks = objXML.getElementsByTagName("Track").length
				For k = 0 to (totTracks-1)
					If (k<totTracks-1) Then szCom = ", " Else szCom = "" End if
					set o17 = objXML.getElementsByTagName("Tracks").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Track" szTracks = szTracks & o18.item(k).text & szCom
					End Select
				Next
			Case "Accessories"
				totAccessories = objXML.getElementsByTagName("Accessory").length
				For k = 0 to (totAccessories-1)
					If (k<totAccessories-1) Then szCom = ", " Else szCom = "" End if
					set o17 = objXML.getElementsByTagName("Accessories").item(0)
					set o18 = o17.childNodes
					Select Case o18.item(k).nodeName
						Case "Accessory" szAccessories = szAccessories & o18.item(k).text & szCom
					End Select
				Next
			End Select
		Next

%>

<html>
<head>
<title>Amazon Light - Details for <% =szProductName %></title>
<meta name="keywords" content="Amazon.com, Amazon webservices, amazon web services, amazon light, amazon lite, amazonlight, amazagoogle, googlezon, amagoogle, amazon.com light, amazon associates, easy search, kokogiak amazon">
<meta name="description" content="Amazon Light - a fast and easy way to search and browse Amazon.com, Amazon Light, an Amazon.com Web Service, Amazon Light by Kokogiak Media">
<link rel="stylesheet" type="text/css" href="ph.css">
</head>
<body bgcolor="#ffffff" link="#222222" alink="#000066" vlink="#666666" text="#000000" marginheight=0 marginwidth=0 topmargin=0 leftmargin=0>
<center><table border=0 cellspacing=0 cellpadding=0 width=100% ><tr bgcolor="#efeecf"><td><img border=0 height=15 width=290 src="nv.gif" align="absmiddle" usemap="#nv"> </td></table></center>
<map name="nv"><area shape='rect' href='default.asp?field-keywords=<% =szTerm %>&sb=<% =szSB %>&typ=<% =szSchType %>&mod=<% =szSchMode %><% If szSB = "o" Then Response.write("&scNode=" & szNode) %>' coords='0,0,52,15'><%
Response.write("<area shape='rect' href='results.asp?sb=" & szSB & "&schMod=books&field-keywords=" & szTerm & "&scNode=000' coords='52,0,96,15'>")
Response.write("<area shape='rect' href='results.asp?sb=" & szSB & "&schMod=electronics&typ=elec&field-keywords=" & szTerm & "&scNode=000' coords='96,0,169,15'>")
Response.write("<area shape='rect' href='results.asp?sb=" & szSB & "&schMod=toys&typ=game&field-keywords=" & szTerm & "&scNode=000' coords='169,0,205,15'>")
Response.write("<area shape='rect' href='results.asp?sb=" & szSB & "&schMod=kitchen&typ=home&field-keywords=" & szTerm & "&scNode=000' coords='205,0,289,15'>")
%></map>
<table cellspacing=5 cellpadding=0 width=100% border=0><tr valign=top><td>
<font face="arial,helvetica" size=2>
<form action="results.asp">
<table cellspacing=0 cellpadding=0 border=0>
<tr valign=top><td rowspan=2>  </td>
<td width=148 rowspan=2>
<font face="arial,helvetica" size=1>
<a href="default.asp?field-keywords=<% =szTerm %>&sb=<% =szSB %>&typ=<% =szSchType %>&mod=<% =szSchMode %><% If szSB = "o" Then Response.write("&scNode=" & szNode) %>"><img src="amzn-logo-sm.gif" alt="Amazon" width="148" height="43" border=0 hspace="0" vspace="0" align=left></a>  </td>
<td align=left><font face="arial,helvetica" size=1><nobr><a href="advsearch.asp">Advanced Search</a> - <a href="http://www.amazon.com" target="_new">Amazon.com Proper</a></nobr><br></font>
</td>
</tr>
<tr valign=bottom>
<td align=center>
	<nobr><input maxLength=256 size=30 name="field-keywords" value="<% =Replace(szTerm,"+"," ") %>"><br><input type=image src="azs.gif" alt="Search for Amazon.com Products" height="20" width="150" border="0" value="Amazon Search" name=AZSch></nobr>
	<input type=hidden value="<% =szSchMode %>" name=schMod><input type=hidden value="<% =szSchType %>" name=typ></form>
</td>
</tr></table>
</td>
<%
'+------------------
'| Include the mini-shopping-cart (ylist.inc)
'+------------------
%>
<td align=right><!-- #INCLUDE FILE="ylist.inc" --></td>
</tr></table>
<hr size=1 color=#006699 noshade=true width=100% ><br>
<table cellspacing=0 cellpadding=3 border=0 width=100% >
	<tr valign=top><td>  </td><td width=150 align=center>
<%
		If (szImageUrlMedium<>"") Then
			Response.write("<a href='" & szImageUrlLarge & "' target='_new'><img border=0 src='" & szImageUrlMedium & "'><br><font size=1 style='font-size:10px;' width='150'>Click to see larger image</font></a><br>")
		Elseif (szImageUrlSmall<>"") Then
			Response.write("<img border=0 align=left src='" & szImageUrlSmall & "'><br>")
		Else
			Response.write(" ")
		End if
		Response.write ("</td><td><font face='arial,helvetica' size=2 style='font-size:16px;'><b>" & szProductName & "</b><br></font>")
		If (szAuthors<>"") Then
			If szSchMode = "books" Then
				Response.write ("<font face='arial,helvetica' size=2 style='font-size:14px;'>by <a href='results.asp?advSearch=1&schMod=books&field-keywords=" & Server.URLEncode(Replace(szAuthors,","," ")) & "'>" & szAuthors & "</a><br>")
			Else
				Response.write ("<font face='arial,helvetica' size=2 style='font-size:14px;'>by " & szAuthors & "<br>")
			End if
		End if

		If (szArtists<>"") Then
			Response.write ("<font face='arial,helvetica' size=2 style='font-size:14px;'>by " & szArtists & "<br>")
		End if

		If (szManufacturer<>"") Then
			Response.write ("<font face='arial,helvetica' size=2 style='font-size:12px;'>" & szManufacturer & "</font><br>")
		End if

		If (szSalesRank <> "") Then
			Response.write ("<font face='arial,helvetica' size=2 style='font-size:12px;'>Sales Rank: <b><font color='darkred'>" & szSalesRank & "</font></b>")
			If (szAvgCustomerRating <> "") Then
				Response.write (" - ")
			Else
				Response.write ("<br>")
			End if
		End if
		If (szAvgCustomerRating <> "") Then
			Response.write ("<font face='arial,helvetica' size=2 style='font-size:12px;'>Avg. Rating: <b><font color='darkred'>" & Round(szAvgCustomerRating,1) & "</font></b> (out of 5)<br>")
		End if

		If (szReleasedate <> "") Then
			Response.write ("Released: " & szReleasedate )
			If (szIsbn <> "") Then
				Response.write (" - ISBN: " & szIsbn & "<br>")
			Elseif (szUpc <> "") Then
				Response.write (" - UPC: " & szUpc & "<br>")
			Else
				Response.write ("<br>")
			End if
		Else
			If (szIsbn <> "") Then
				Response.write ("ISBN: " & szIsbn & "<br>")
			Elseif (szUpc <> "") Then
				Response.write ("UPC: " & szUpc & "<br>")
			End if
		End if


		If (szFeatures <> "") Then
			Response.write ("<b>Features</b>:<br>" & szFeatures & "<br>")
		End if

		If (szMedia <> "") Then
			Response.write(szMedia)
			If (szPlatform <> "") Then
				Response.write(" for " & szPlatform & "<br>")
			Else
				Response.write("<br>")
			End if
		End if


		If (szEsrbRating <> "") Then
			Response.write ("<b>Rated:</b>:	" & szEsrbRating & "<br>")
		End if

		If (szMpaaRating <> "") Then
			Response.write ("<b>Rated:</b>:	" & szMpaaRating & "<br>")
		End if

		If (szDirectors <> "") Then
			Response.write ("<b>Directed by</b>:<br> " & szDirectors & "<br>")
		End if

		If (szActors <> "") Then
			Response.write ("<b>Starring</b>:<br>" & szActors & "<br>")
		End if

		Response.write ("</td><td align=right><table border=0 cellpadding=0 cellspacing=0><tr><td><font face='arial,helvetica' size=2 style='font-size:14px;'>")
		If ((szListprice <> "") AND (szListprice <> szOurPrice)) Then
			Response.write ("List Price: <b><strike>" & szListprice & "</strike></b><br>")
		End if
		If (szOurprice <> "") Then
			Response.write ("Our Price: <b><font color='red'>" & szOurPrice & "</font></b><p>")
		End if

		Response.write ("<center><form method='GET' action='detpage.asp'>")
		If (szAvailability <> "") Then
			Response.write ("<font size=1>This items availability: <u>" & szAvailability & "</u></font><p>")
		End if
		Response.write ("<table border=0><tr><td><input type='image' src='add_l.gif' border='0' width='200' height='20' name='add-to-cart' value='Add to Your List'><input type='hidden' name='addasin' value='1'><input type='hidden' name='sb' value='" & szSB & "'><input type='hidden' name='asin' value='" & szAsin & "'><input type='hidden' name='field-keywords' value='" & szTerm & "'><input type='hidden' name='schMod'  value='" & szSchMode & "'><input type='hidden' name='typ' value='" & szSchType & "'>")
		Response.write ("</td></tr></form></table>")

		Response.write ("<br><font size=2>Or, click here to view<br><a href='http://www.amazon.com/exec/obidos/ASIN/" & szAsin & "/ref=nosim/kokogiak-20' target='_new'><font color='darkred'>Full Amazon.com Detail Page</font></a></font></center>")

		Response.write ("</td></tr></table></td><td>  </td></tr></table>")

		If (szSimilarProducts <> "") Then
			Response.write("<center><b>Related Items</b>:<hr size=1 color=#006699 noshade='true'>")
			rgSims = Split(szSimilarProducts," ")
			For ss = 0 to UBound(rgSims)
				Response.write("<a href='detpage.asp?asin=" & rgSims(ss) & "&field-keywords=" & szTerm & "&schMod=" & szSchMode & "&type=" & szSchType & "&sb=" & szSB & "'><img src='http://images.amazon.com/images/P/" & rgSims(ss) & ".01.THUMBZZZ.jpg' border=0 hspace=2></a>")
			Next
			Response.write("<hr size=1 color=#006699 noshade='true'></center>")
		Else
			Response.write("<p>")
		End if


		Response.write("<table cellspacing=0 cellpadding=5 border=0 width=80% ><tr><td>  </td><td><font face='arial,helvetica' size=2 style='font-size:12px;'>")
		If (totReviews>0) Then
			Response.write ("<b><font size=3>Top Customer Reviews</font></b><br>")
			For zz = 0 to (UBound(rgReviews)-1)
				Response.write(rgReviews(zz) & "<hr>")
			Next
		End if
		Response.write ("</td></tr></table><font size=2 style='font-size:12px;'>")

	Next

	Set objXML = Nothing
	Set objXSL = Nothing

Else

	Response.write ("<div id='bin'>Sorry, No Results found for ASIN #<b>" & szAsin & "</b> in " & szMode & ".</div>")

End if

%>
</td></tr>
</table>
<center><font face='arial,helvetica' size=2>
<p><br><br>
<b>At Amazon.com Proper</b><br>
<table border=0 cellspacing=0 cellpadding=0 width=100% ><tr bgcolor="#efeecf"><td align="center"><font face="arial,helvetica" size=2>
<a href="http://www.amazon.com/exec/obidos/tg/stores/recs/instant-recs/-/recs">Recommendations</a> -
<a href="http://www.amazon.com/exec/obidos/tg/stores/static/-/gateway/international-gateway">International</a> -
<a href="http://www.amazon.com/exec/obidos/account-access-login">Your Account</a> -
<a href="http://www.amazon.com/exec/obidos/wishlist">Wish List</a> -
<a href="http://www.amazon.com/exec/obidos/tg/browse/-/909656">Today's Deals</a> -
<a href="http://www.amazon.com/exec/obidos/tg/browse/-/508510">Help</a><br> 
 </td></table></center></body></html>